Cara Lengkap Menggunakan Modul GPS Di Arduino

 

Modul Gps banyak digunakan pada zaman sekarang ini, karena modul gps ini sangat berguna untuk mengetahui titik lokasi tertentu dengan menggunakan bantuan satelit

Satelit mengirimkan sinyal radio kebumi untuk memberi tahu lokasi gps berada  

Pin Out pada modul GPS

Terdapat 4 pin out pad modul gps, yaitu:

• Pin GND untuk sumber tegangan ground dari arduino atau power suplay lainnya
• Pin TX yang fungsinya sebagai pin untuk komunikasi serial
• Pin RX fungsinya juga digunakan sebagai komunikasi serial
• Pin VCC untuk sumber tegangan 5v dc dari arduino atau dari power suplay

Indikator led yang ada pada modul juga terdapat artinya

• Led tidak berkedip berarti modul sedang mencari satelit untuk menghitung kalkulasi titik lokasi
• Led berkedip setiap 1 detik artinya titik lokasi ditemukan

Mengakses modul gps dengan arduino tidaklah sulit, caranya yaitu

Siapkan komponen terlebih dahulu antara lain :

• Arduino uno
• Modul GPS Neo6MV2
• Kabel jumper
• Laptop yang sudah terinstal arduino ide

Selanjutnya rangkai modul gps dengan arduio seperti pada gambar dibawah ini

Keterangan:

Hubungkan pin GND pada modulgps ke pin GND pada arduino

• Pin TX hubungkan ke pin 4 pada arduino
• Pin RX hubungkan ke pin 3 pada arduino
• Pin VCC hubungkan ke pin 5v pada arduino

Kemudian setelah terhubung semua, selanjutnya memprogram arduino supaya bisa terkoneksi dengan modul gps, caranya sebagai berikut

• Buka aplikasi arduino ide pada laptop kalian
• Download library  TinyGPS

• Kemudian copy program dibawah ini dan pastekan ke project arduino ide kalian

[program]

#include <TinyGPS++.h>
#include <SoftwareSerial.h>

const int RXPin = 3, TXPin = 4;
const uint32_t GPSBaud = 9600; //Default baud of NEO-6M is 9600


TinyGPSPlus gps; // the TinyGPS++ object
SoftwareSerial gpsSerial(RXPin, TXPin); // the serial interface to the GPS device

void setup() {
  Serial.begin(9600);
  gpsSerial.begin(GPSBaud);

  Serial.println(F("Arduino - GPS module"));
}

void loop() {
  if (gpsSerial.available() > 0) {
    if (gps.encode(gpsSerial.read())) {
      if (gps.location.isValid()) {
        Serial.print(F("- latitude: "));
        Serial.println(gps.location.lat());

        Serial.print(F("- longitude: "));
        Serial.println(gps.location.lng());

        Serial.print(F("- altitude: "));
        if (gps.altitude.isValid())
          Serial.println(gps.altitude.meters());
        else
          Serial.println(F("INVALID"));
      } else {
        Serial.println(F("- location: INVALID"));
      }

      Serial.print(F("- speed: "));
      if (gps.speed.isValid()) {
        Serial.print(gps.speed.kmph());
        Serial.println(F(" km/h"));
      } else {
        Serial.println(F("INVALID"));
      }

      Serial.print(F("- GPS date&time: "));
      if (gps.date.isValid() && gps.time.isValid()) {
        Serial.print(gps.date.year());
        Serial.print(F("-"));
        Serial.print(gps.date.month());
        Serial.print(F("-"));
        Serial.print(gps.date.day());
        Serial.print(F(" "));
        Serial.print(gps.time.hour());
        Serial.print(F(":"));
        Serial.print(gps.time.minute());
        Serial.print(F(":"));
        Serial.println(gps.time.second());
      } else {
        Serial.println(F("INVALID"));
      }

      Serial.println();
    }
  }

  if (millis() > 5000 && gps.charsProcessed() < 10)
    Serial.println(F("No GPS data received: check wiring"));
}

• Cek pada menu tools kemudian board untuk memastikan jenis board mikrokontroler yang kalian pakai
• Cek port sudah terhubung atau belum dengan cara pilih menu tools kemudian port, pilih COM yang aktif
• Setelah itu upload program dengan mengklik icon centang pada pojok kiri atas arduino ide
• Tunggu sampai upload done, kemudian buka serial monitor kalian, disana akan muncul informasi dari gps seperti koordinat, waktu, tanggal dan lainnya

Itulah cara untuk mengakses modul gps dengan arduino, semoga bermanfaat